Einfache Windows-Admin-Frage: Welcher Mitarbeiter ist in diesem Moment und seit wann an welchem PC eingeloggt?

Einfache Antwort, kurz und knackig: Batch!
Mit Hilfe von PsLoggedOn, welches sich im selben Verzeichnis befinden muss wie das Skript:

@echo on & Color 9f & setlocal
for /f "Tokens=1" %%c in ('net view /domain:"%USERDOMAIN%"^|Findstr /L /C:"\\"') do (
 for /f "Tokens=*" %%u in ('PsLoggedOn -L %%c^|find /i "%USERDOMAIN%\"') do (
  echo %%c %%u
 )
)
endlocal
pause
goto :EOF

via (leicht angepasst)

Das Bild zeigt das gekürzte PsLoggedOn-Script, welches zu allen eingeschalteten Domänencomputern die eingeloggten Nutzer anzeigt.

Der Befehl

sc

aus der Windows Konsole, mit dem sich die Windows Dienste steuern lassen, hat einen entscheidenden Nachteil: Es sind keine Wildcards möglich, der Dienstname muss exakt so angegeben sein, wie er im System registriert ist.
Somit sind

sc stop

und

sc delete

schnell am Ende ihrer Möglichkeiten.

Angenommen ich habe einen oder mehrere Dienste mit einem bestimmten Namenspattern, die angesprochen und verarbeitet werden müssen. Das Namenspattern könnte beispielsweise sein: „[beliebige Zeichenkette]Manager“. Weitere Platzhalter wie „[beliebig]win[beliebig]svc[beliebig]“ sind ebenfalls möglich.

Im Gegensatz zu sc bietet

wmic service

entsprechende Möglichkeiten, mit Wildcards und komplexeren Anfragen umzugehen:

Abfragen:

REM Laufende Dienste mit "Manager" im Namen in der Konsole abfragen und einzelne Informationen filtern
wmic service where (name like "%%Manager%%" and state="running") get caption, name, state, status
REM Export aller Prozesse mit "Manager" im Namen als HTML exportieren
wmic service where (name like "%%Manager%%") get /format:hform >> C:/services.html
REM Namenspattern [beliebig]win[beliebig]svc[beliebig] suchen
wmic service where (name like "%%win%%svc%%") get caption, name, state

Das Bild zeigt den Windows Konsolenbefehl wmic service mit Paaternsuche

Starten/Stoppen/Löschen:

wmic service where (name like "%%win%%svc%%") call startservice
wmic service where (name like "%%Manager%%" and state="running") call stopservice
wmic service where (name like "%%Manager%%") call delete

via, via, via

Auch dieser Artikel reiht sich in die Liste der Software-Batch-AD-Deployment-Guides ein.
Im Falle von HipChat wird der Artikel recht kurz, denn hier passiert nichts ungewöhnliches.

Vorbereitung

Das Bild zeigt das HipChat Deployment Verzeichnis mit seinen üblichen DateienDer aktuellste HipChat-Installer (für Windows) ist als .exe immer unter dieser URL verfügbar.
Anschließend wird wieder ein übliches Deployment-Verzeichnis auf einem für die PCs verfügbaren Netzlaufwerk erstellt: Installer, Installer-Batch, allowedPCs.txt und deniedPCs.txt (mehr Informationen zum Clientfilter hier). Im Standardfall (so auch in diesem Deployment-Script) wird die deniedPCs.txt benutzt, um einzelne Clients von der Verteilung auszuschließen. Die Textdatei muss dann Computernamen enthalten, einen pro Zeile.
Der HipChat-Installer muss folgendermaßen umbenannt werden: „HipChat_[Version].exe“ und der Versionsstring muss in das Deployment-Script in Zeile 11.

Deployment-Script

19.09.2016: Version 4.27.1.1658 getestet und verteilt.

Hinweis: Wer nicht nur ein Update sondern eine komplette Reinstallation von Hipchat im Netzwerk ausrollen will, kann mein angepasstes Script – hier als Download – nutzen. Die benötigte VersionCompare.exe erhaltet ihr hier.

Hier das Script für ein normales Update:

@echo off && color 9f && setlocal
set wd=\\lea\Deployment\Software\Hipchat
set log=%wd%\hipchat.log
set tools=\\lea\Deployment\Sonstiges\tools
set hipEL=999
set instversion=0.0
set versionEL=9
set exepath=none
set retry=0
REM:: ######## EDIT THIS ####
set newversion=4.1658
REM:: #######################


REM:: Clientfilter: nur die Computer aus der allowedPCs.txt dürfen installieren
::for /f %%f in (%wd%\allowedPCs.txt) do if "%computername%"=="%%f" goto check
::goto end

REM:: Clientfilter: die Computer aus der deniedPCs.txt dürfen nicht installieren
for /f %%f in (%wd%\deniedPCs.txt) do if "%computername%"=="%%f" goto end

:check
if exist "C:\Program Files (x86)\Atlassian\HipChat4\HipChat.exe" set exepath="C:\Program Files (x86)\Atlassian\HipChat4\HipChat.exe"
::if exist "c:\Program Files (x86)\Skype\Phone\skype.exe" set exepath="c:\Program Files (x86)\Skype\Phone\skype.exe"
if %exepath%==none echo %date% %time:~0,8% - %computername% findet das .exe Verzeichnis nicht && goto taskkill
goto checkversion

:checkversion
for /f "tokens=1-3" %%i in ('%tools%\sigcheck %exepath%') do ( if "%%i %%j"=="File version:" set instversion=%%k )
%tools%\VersionCompare.exe %instversion% %newversion%
set versionEL=%errorlevel%
if "%versionEL%"=="-1" goto taskkill
if "%versionEL%"=="0" echo %date% %time:~0,8% - %computername% hat bereits %instversion% installiert >> %log% & goto end
if "%versionEL%"=="1" echo %date% %time:~0,8% - %computername% hat bereits %instversion% (neuer) installiert >> %log% & goto end
goto end

:taskkill
TASKKILL /f /im hipchat.exe
goto install

:install
echo %date% %time:~0,8% - %computername% installiert... >> %log%
::msiexec.exe /i %wd%\deploy\%newversion%\SkypeSetup.msi /qn /norestart FEATURE_IEPLUGIN=0 FEATURE_FFPLUGIN=0
start /w %wd%\HipChat_%newversion%.exe /verysilent /norestart /restartapplications /lang=german /lang=1031 /64 /64bit /x64
set hipEL=%errorlevel%
if %hipEL%==1618 goto retry REM:: msiexec process in use, installation already in progress (eg. windows updates running)
if %hipEL%==1602 goto retry REM:: user canceled installation (eg. taskkill)
if %hipEL%==1603 goto retry REM:: fatal error, some use it for "already installed" (eg. java)
if %hipEL%==1638 goto uninstall REM:: another product is already installed, denies an update
if %hipEL%==1625 goto uninstall REM:: skype installer sometimes threw this one, don't know why
set hipEL=%errorlevel%
echo %date% %time:~0,8% - %computername% hat Version %newversion% mit EL %hipEL% abgeschlossen >> %log%
md %wd%\done\%computername%
goto end

:retry
if %retry%==1 goto retryfailed
echo %date% %time:~0,8% - %computername% hatte den Fehler %hipEL%, retry in 500Sek... >> %log%
set retry=1
REM:: 5 Minuten warten
ping localhost -n 500 > nul
goto taskkill

:retryfailed
echo _!_ %date% %time:~0,8% - %computername% hat die Installation abgebrochen, RETRY FAILED! >> %log%
goto end

:uninstall
if %retry%==1 goto retryfailed
TASKKILL /f /im hipchat.exe
echo %date% %time:~0,8% - %computername% deinstalliert Version %instversion%... >> %log%
start /w "" "C:\Program Files (x86)\Atlassian\HipChat4\unins000.exe" /s /silent /qn
del /q /s "C:\Program Files (x86)\Atlassian"
echo %date% %time:~0,8% - %computername% - %instversion% deinstalliert, retry... >> %log%
set retry=1
goto taskkill

:end
endlocal
exit

Und das war’s auch schon. Bei einem Update muss nur die neue .exe-Datei heruntergeladen und die Version in Zeile 11 angepasst werden.
Das Script kommt als Computer-Startscript in das GPO und schon startet die Verteilung:
Das Bild zeigt die Logausgaben des HipChat-Deployments
Das Bild zeigt das Deployment der 1648er Version anhand des allnew-Update-Scripts (siehe Hinweis und Download oben). Dabei wird an jedem PC, unabhängig der installierten Version (deswegen wird überall „Version 0.0“ deinstalliert), HipChat komplett deinstalliert und neu installiert. Beim Umstieg auf 1648 würde ich das empfehlen, weitere Update werden ich auch wieder mit dem normalen Script erledigen.

Vorweg kurz die Definition von „Bloatware“:
Das Bild zeigt den Installationsdialog einer Software, in dem etliche zusätzliche und meistens unerwünschte Programme mitinstalliert werden sollen (Bloatware)Bloatware, manchmal auf Crapware genannt, beschreibt unerwünschte Software, die bei der Installation einer gewünschten Software mitinstalliert wird. Meistens kann der Nutzer während der Installation diese Bloatware deaktivieren. Gerne sind diese Dialoge aber auch bewusst getarnt, sodass der User in der Eile der Installation schnell den falschen Button drückt.
Selbst für waschechte ITler bleibt das Deaktivieren von Checkboxen und aufmerksame Betrachten der Installationsdialoge einfach lästig.

Unchecky ist unsere Rettung!
Die kleine kostenlose Windows Freeware hilft euch folgendermaßen:

  • Sie entfernt Bloatware-Dialoginhalte oder sogar komplette Dialoge – wenn möglich.
  • Unchecky deaktiviert automatisch alle Häckchen von Bloatware und setzt Radiobuttons auf die richtige Position, sodass trotz einfachem „Weiter“-Klicken keine Bloatware mehr installiert werden sollte (siehe unten).
  • Das Tool warnt mit einem Popup, falls doch mal Bloatware übersehen wurde (siehe unten).
  • Unchecky installiert sich selbst als Windows Hintergrunddienst, ist also nach der Installation immer aktiv und aktualisiert sich im Falle neuer Versionen auch unsichtbar von selbst.

Das Bild zeigt einen Installationsdialog vorher (mit aktivierten Bloatware-Optionen) und nachher (Optionen dank Unchecky deaktiviert)
Das Bild zeigt einen Unchecky Warndialog, der darauf hinweißt, dass die Installation noch aktivierte Bloatware enthält.

Heißt: Nie wieder Bloatware und das ohne jeglichen neuen Verwaltungsaufwand! Ich verwende die Software selbst schon lange und installiere sie auch bei Freunden und Verwandten. Einfach TOP!

Neu in meiner Software-Deployment Auflistung ist ab jetzt KeePass 2, eine ziemliche gute und erweiterbare Passwortmanagement-Freeware.
Zu KeePass selbst werde ich in Zukunft noch einige Artikel schreiben, von der Installation bis zur Integration in Browser und Smartphone. Jetzt erstmal schnell das Deployment im Windows Active Directory via Batch Script, im üblichen Stil.

Vorbereitung

Das Bild zeigt die vielen Deploymentparameter und -optionen des KeePass 2 InstallersDer .exe Installer von der Homepage (Pro Version) liefert beim Aufruf mit dem Parameter „/?“ eine lange Liste von Optionen zur Anpassung der Installation. Diese findet ihr hier auch nochmal zur besseren Lesbarkeit in HTML Form.
Praktisch: Ihr könnt mit allen Parametern die Installation anpassen und bei der ersten Installation mit dem Parameter /SAVEINF=filename das Set an Optionen in eine Konfigurationsdatei speichern. Für die nächste Installation reicht als Parameter dann nur noch /LOADINF. So lassen sich beispielsweise unterschiedliche Deploymentprofile erstellen und nutzen.

Plugins

Eine der Stärken von KeePass ist die starke Erweiterbarkeit mit Hilfe der vielen Plugins und Tools. Die Installation und Verteilung ist bei fast allen relativ einfach: es reicht schon die entsprechende Plugin-Datei (z.B. .plgx) in das Programmverzeichnis zu legen, ggf. auch in einen seperaten „plugins“ Unterordner für eine verbesserte Übersicht. Beim nächsten Start von KeePass wird das Plugin automatisch erkannt und geladen.
Aus diesem Grund kopiert das Deployment-Script benötigte Plugins einfach nur in den Installationsordner – fertig!

Deployment

Aktuell: Version 2.34 via .exe
Das im Skript verwendete Programm VersionCompare ist eine Eigenprogrammierung und hier als Download verfügbar.

Code anzeigenDen Code könnt ihr bequem mit den Links/Rechts Pfeiltasten horizontal bewegen.

@echo off && color 9f && setlocal

set wd=\\lea\Deployment\Software\KeePass
set log=%wd%\keepass.log
set tools=\\lea\Deployment\Sonstiges\tools
set instversion=0.0
set versionEL=9
set regEL=999
set exepath=none
set retry=0

REM:: ######## EDIT THIS ####
set newversion=2.34
REM:: #######################

REM:: Clientfilter: nur die Computer aus der allowedPCs.txt dürfen installieren
REM::for /f %%f in (%wd%\allowedPCs.txt) do if "%computername%"=="%%f" goto check
REM::goto end

REM:: Clientfilter: die Computer aus der deniedPCs.txt dürfen nicht installieren
for /f %%f in (%wd%\deniedPCs.txt) do if "%computername%"=="%%f" goto end

:check
if exist "c:\Program Files (x86)\KeePass2\KeePass.exe" set exepath="c:\Program Files (x86)\KeePass2\KeePass.exe"
if exist "c:\Program Files\KeePass2\KeePass.exe" set exepath="c:\Program Files\KeePass2\KeePass.exe"
if %exepath%==none goto install
goto checkversion

:checkversion
for /f "tokens=1-3" %%i in ('%tools%\sigcheck %exepath%') do ( if "%%i %%j"=="File version:" set instversion=%%k )
%tools%\VersionCompare.exe %instversion% %newversion%
set versionEL=%errorlevel%
if "%versionEL%"=="-1" goto install
if "%versionEL%"=="0" echo %date% %time:~0,8% - %computername% hat bereits %instversion% installiert >> %log% & goto plugins
if "%versionEL%"=="1" echo %date% %time:~0,8% - %computername% hat bereits %instversion% (neuer) installiert >> %log% & goto plugins

:install
echo %date% %time:~0,8% - %computername% installiert... >> %log%
TASKKILL /f /im KeePass.exe
start /w %wd%\KeePass-%newversion%.exe /VERYSILENT /SP- /SUPPRESSMSGBOXES /LOG="logs/%computername%.log" /NORESTART /CLOSEAPPLICATIONS /SAVEINF="standardsetup.inf" /DIR="%ProgramFiles%\KeePass2" /GROUP="KeePass 2"
set kpel=%errorlevel%
if %kpel%==1618 goto retry REM:: msiexec process in use, installation already in progress (eg. windows updates running)
if %kpel%==1602 goto retry REM:: user canceled installation (eg. taskkill)
if %kpel%==1603 goto retry REM:: fatal error, some use it for "already installed" (eg. java)
if %kpel%==1638 goto retry REM:: another product is already installed, denies an update
echo %date% %time:~0,8% - %computername% hat Version %newversion% mit EL %kpel% abgeschlossen >> %log%
goto plugins

:plugins
REM:: copy plugins
if exist "c:\Program Files (x86)\KeePass2\KeePass.exe" xcopy /Y /S /I "%wd%\plugins" "c:\Program Files (x86)\KeePass2\plugins"
if exist "c:\Program Files\KeePass2\KeePass.exe" xcopy /Y /S /I "%wd%\plugins" "c:\Program Files\KeePass2\plugins"
goto end

:retry
if %retry%==1 goto retryfailed
echo %date% %time:~0,8% - %computername% hatte den Fehler %kpel%, retry in 500Sek... >> %log%
set retry=1
REM:: 5 Minuten warten
ping localhost -n 500 > nul
goto install

:retryfailed
echo _!_ %date% %time:~0,8% - %computername% hat die Installation abgebrochen, RETRY FAILED! >> %log%
goto end

:end
endlocal
exit

Nur ein kurzer Beitrag zur Thematik, wie man gelöschte Benutzer eines Active Directory wiederherstellen kann.

Laut eines Microsoft Hilfeartikels kann man das integrierte Windows Server Tool ldp.exe benutzen, welches das Anzeigen und Wiederherstellen von gelöschten Elementen ermöglicht. Dieses Tool ist unglaublich einfach zu bedienen, übersichtlich sowie besonders effektiv…
Das Bild zeigt das unübersichtliche Windows Server Tool ldp.exe, mit dem (angeblich laut Microsoft Hilfe) gelöschte AD-Benutzer wiederhergestellt werden können

Also, Finger weg von ldp.exe.
Statt dessen mal wieder ein Blick auf die Sysinternals Tools, vor allem ADRestore.exe.
Dieses einfache Kommandozeilentool kann in wenigen Sekunden ein AD Objekt wiederherstellen:
Das Bild zeigt die Kommandozeilenausgabe des Sysinternals Tools adrestore.exe, welches recht einfach zu bedienen ist. Mit "adrestore.exe -r [name]" wird ein gelöschtes Benutzerobjekt gefunden und einfach wiederhergestellt.

Vielleicht ebenfalls interessant: die GUI-Version von ADRestore namens „ADRestore.NET:
Das Bild zeigt eine grafische Oberfläche des Kommandozeilentools ADRestore mit vielen Extras und Informationen zu den Objekten

Und ebenfalls einen Blick wert ist diese Sammlung von verschiedensten Active Directory Restore Tools für jede Art von Wiederherstellung: LINK

Nur eine kurze Zusammenfassung, wie ich den Bildschirm meines Android Smartphones gerade auf meinen PC geschickt habe. Live Screen Sharing eben, ziemlich easy:

Android -> PC

Installiert die Mirror Beta App auf eurem Smartphone und die AllCastReciever Extension in eurem Chrome auf dem PC. Letztere startet ihr dann über das Windows Statmenü, es ist keine typische Chrome Erweiterung.

Wenn nun beide Geräte im selben Netzwerk und gestartet sind, müssten sie sich sehen:
android-smartphone-screen-sharing-to-pc-mirror-allcast-devicesandroid-smartphone-screen-sharing-to-pc-mirror-allcast-screen

AllCast fähige Geräte

Aber…

Das Bild ist von der Qualität her okay, es läuft mit ca. 10fps, also leicht ruckelig. Ansonsten macht es aber einen guten Eindruck. Touch wird mit einem Punkt und einer kleinen von dem Punkt ausgehenden „Welle“ auf dem PC symbolisiert.
Ich weiß nicht ob es möglich ist auf ein Gerät zu streamen, dass nicht im selben LAN/WLAN ist, praktisch via IP. Neben PCs funktioniert das auch auf Apple TV und Fire TV. Übertragung zum Chromebook funktioniert angeblich nicht.
Und ich habe, weil es schnell gehen musste, mir noch keine alternativen Anbieter für Android->PC-Screensharing rausgesucht, vielleicht gibt es bessere Apps dafür. Die Bewertungen des AllCast Recievers sind auch mäßig, vermutlich gibt es für die PC-Seite auch bessere Empfänger.
Kennt jemand gute Screensharing Lösungen?