Aus irgendeinem Grund habe ich lange Zeit nicht gewusst, dass es If Else in Batch gibt…
Ich hatte bereits ein Tutorial zum Kombinieren mehrerer Befehle in einer Zeile geschrieben. Damit kann ich so etwas wie If Else vortäuschen:

if not 0==1 echo dies & echo das & del jenes.txt & goto korrekt
echo foo & echo bar & del bullshit.txt & goto falsch

Dabei gibt es echtes If… Else… in Batch!
Parameter abfangen könnte also so aussehen:

if /i %action%==triggered-restart (
if exist %restartdir% call :kill-server & rd %restartdir% /s /q
goto end
) 

if /i %action%==start-server (
tasklist |find /i "IQB_Server.exe"
if not %errorlevel%==0 start IQB_Server.exe
goto end
)

if /i %action%==check-status (
tasklist |find /i "IQB_Server.exe"
if %errorlevel%==1 (
echo Serverprozess nicht gefunden.
) else (
echo Serverprozess gefunden
)
pause
goto end
)

if /i %action%==force-restart (
call :kill-server
goto end
)

if /i %action%==daily-restart (
call :kill-server
goto end
)

if /i %action%==? (
call :help
) else ( 
if /i %action%==help (
call :help
) else ( 
if /i %action%==hilfe (
call :help
) else ( 
if /i %action%==usage (
call :help
))))

Man achte auf die Möglichkeit der tiefen Verschachtelung von If Else. Es wird zwar schnell unübersichtlich mit den Klammern aber es funktioniert, wenn man sie richtig setzt.

Wichtig: Nach dem Statement des If und nach dem Else unbedingt ein Leerzeichen lassen, sonst gibts Fehler. Fehlerhaft wäre also:

REM Fehlerhaftes Beispiel
if %test%==1(
echo foo
) else(
echo bar
)

Ein funktionierender Einzeiler:

if %test%==1 (echo foo)else (echo bar)

Es ist übrigens genauso auch ein If Not [Statement] ( ) möglich.

Zeit messen ist mit Batch kein Problem und oftmals eine nette Spielerei.

Code:

set /a timerstart=((1%time:~0,2%-100)*60*60)+((1%time:~3,2%-100)*60)+(1%time:~6,2%-100)
REM packing zip archive
%wd%\7za.exe a -bd -ssw "%job-ziel%.zip" "%job-quelle%" > nul
set /a timerstop=((1%time:~0,2%-100)*60*60)+((1%time:~3,2%-100)*60)+(1%time:~6,2%-100)
set /a timeseks=(%timerstop%-%timerstart%)
set /a timemins=(%timerstop%-%timerstart%)/60
echo Sekunden: %timeseks% -- Minuten: %timemins%

Erläuterung:
Also, timerstart nimmt die aktuelle Uhrzeit und rechnet aus, wieviele Sekunden seit 00:00 Uhr verstrichen sind.
Der 2. Timer, timerstop, rechner ebenfalls die Sekunden seit 00 Uhr aus. Zieht man diese jetzt von der Startzeit ab so bleibt die Anzahl in Sekunden übrig, die zwischen den Timern verstrichen ist.
Das bedeutet natürlich auch, dass eine Zeitberechnung von einem Tag in den nächsten nicht funktioniert. Start und Stop müssen zwischen 00 Uhr und 23:59 Uhr des selben Tages liegen.

Details zu dieser Art der Zeitmessung:
Diese Berechnung ist bereits eine optimierte Variante. Grundsätzlich würde in 80% der Fälle auch

set /a timerstart=((%time:~0,2%)*60*60)+((%time:~3,2%)*60)+(%time:~6,2%)

funktionieren; diese Variante findet man auch überall im Netz.
Ich beobachtete jedoch Probleme bei Zeitberechnungen, wenn mit den Zahlen „08“ und „09“ hantiert wurde.
Also beispielsweise um 16:08:09 Uhr wird ein Timer aktiviert. Dann rechnet dieser eigentlich
((16)*60*60)+((08)*60)+(09)
Batch kommt damit aber nicht klar, da er dezimale Zahlen und oktale Zahlen durcheinander bringt. Um trotzdem mit Uhrzeiten mit „08“ und „09“ rechnung zu können habe ich die Zeile ergänzt:

set /a timerstart=((1%time:~0,2%-100)*60*60)+((1%time:~3,2%-100)*60)+(1%time:~6,2%-100)

Nun wird also bei 16:08:09 gerechnet:
((116-100)*60*60)+((108-100)*60)+(109-100)
Funktioniert 🙂

Update:
Eine etwas komplexere Lösung mit der Berücksichtigung des Datums wurde von einem Leser via Kommentar eingereicht:

@echo off

REM dynamisch mit %TIME% oder Zahlenformat des endtime Beispiels nehmen
set starttime=%TIME%
set endtime=00:15:26,92
set startdate=08.09.2012
set enddate=09.09.2012

REM einstellige Uhrzeiten korrigieren
set starttime=%starttime: =%
set endtimehh=%endtime:~1,1%
if ‘%endtimehh%’ == ‘:’ set endtime=0%endtime%
echo endtime: %endtime%

set starttimehh=%starttime:~1,1%
if ‘%starttimehh%’ == ‘:’ set starttime=0%starttime%
echo starttime: %starttime%

set /a timerstart=((1%starttime:~0,2%-100)*60*60)+((1%starttime:~3,2%-100)*60)+(1%starttime:~6,2%-100)
echo timerstart: %timerstart%

set /a daymodifier=86400*((1%enddate:~0,2%)-(1%startdate:~0,2%))
rem set daymodifier=86400
echo daymodifier: %daymodifier%

set /a timerstop=(((1%endtime:~0,2%-100)*60*60)+((1%endtime:~3,2%-100)*60)+(1%endtime:~6,2%-100))+%daymodifier%
echo timerstop: %timerstop%

rem =======================

set /a timeseks=(%timerstop%-%timerstart%)
echo Sekunden: %timeseks%

set /a timemins=((%timerstop%-%timerstart%)/60)
echo Minuten: %timemins%

set /a timeminsseks=((((%timerstop%-%timerstart%)/60)*60)-(%timerstop%-%timerstart%))*-1
echo Zeit: %timemins%:%timeminsseks%

pause